Function rxSerialTask2

ESP32_AP-Flasher/src/serialap.cpp:713–771

}

void rxSerialTask2(void* parameter) {
    char rxStr[100] = {0};
    int rxStrCount = 0;
    uint32_t modemResetHoldoff = millis();
    char lastchar = 0;
    time_t startTime = millis();
    int charCount = 0;
    Serial2.begin(115200, SERIAL_8N1, FLASHER_DEBUG_TXD, FLASHER_DEBUG_RXD);
    while (rxSerialStopTask2 == false) {
        while (Serial2.available()) {
            lastchar = Serial2.read();
            charCount++;

            // debug info
            Serial.write(lastchar);

            rxStr[rxStrCount] = lastchar;
            if (lastchar == '\n' || lastchar == '\r') {
                if (strncmp(rxStr, "receive buffer full, drop the current frame", 43) == 0 && millisDiff(modemResetHoldoff) > 20000) {
                    modemResetHoldoff = millis();
                    vTaskDelay(100 / portTICK_PERIOD_MS);
                    config.runStatus = RUNSTATUS_STOP;
                    Serial.println("IEEE802.15.4 modem stuck case detected, resetting...");
                    APTagReset();
                    vTaskDelay(1000 / portTICK_PERIOD_MS);
                    Serial.println("bringing AP online again");
                    if (bringAPOnline()) {
                        config.runStatus = RUNSTATUS_RUN;
                        Serial.println("Finished!");
                    } else {
                        Serial.println("Failed!");
                    }
                    logLine("IEEE802.15.4 modem reset " + (config.runStatus == RUNSTATUS_RUN) ? ("ok") : ("failed"));
                }
                rxStrCount = 0;
                memset(rxStr, 0, sizeof(rxStr));
            } else if (rxStrCount < sizeof(rxStr) - 2) {
                rxStrCount++;
            } else {
                rxStrCount = 0;
                memset(rxStr, 0, sizeof(rxStr));
            }
        }
        vTaskDelay(1 / portTICK_PERIOD_MS);

        time_t currentTime = millis();
        if (currentTime - startTime >= 1000) {
            if (charCount > 6000) {
                rxSerialStopTask2 = true;
                Serial.println("Serial monitor stopped because of flooding (" + String(charCount) + " characters per second)");
            }
            startTime = currentTime;
            charCount = 0;
        }
    }
    Serial2.end();
    Serial.println("Exiting AP serial monitor");
    vTaskDelete(NULL);